Peace - Taming Assist Macro

[Ace Mason]

I use this macro when raising taming. Works well if you have a pet to help tank a bit until you get off a successful peace attempt, or while inside a workshop for overland taming. It will prompt for a target to tame, attempt to peace until successful, set your taming skill to raise, and then tame until peace timer is ready to expire (default is 3 taming attempts or about 45 seconds). Once a creature is tamed it will use Animal Lore (I like to check stats), Lock your taming, clear the target, and give you a notification that taming was successful. Hope this helps the up and coming tamers.

//Set the creature to tame
if not @findobject "TameTarget"
  headmsg "Select creature to tame"
  promptalias 'TameTarget'
endif
//Start with peacemaking
if @findobject 'TameTarget'
  @clearjournal
  useskill "peacemaking"
  waitfortarget 1000
  target! "TameTarget"
  //pause for failed attempt
  pause 6500
  //if successful peace add time for the success timer and begin taming
  if @injournal "You play successfully" "system"
    pause 3500
    //set taming to gain
    if skillstate 'Animal Taming' == 'locked'
      setskill 'Animal Taming' 'up'
    endif
    //attempt to tame 3x (adjust for peace duration)
    for 3
      useskill "animal taming"
      waitfortarget 1000
      target! "TameTarget"
      pause 14000
      //clear "TameTarget" when successfully tamed
      if not gray "TameTarget"
        //Lore the fresh tame to see stats
        useskill "animal lore"
        waitfortarget 1000
        target! "TameTarget"
         //Clear Tame Target
        @unsetalias "TameTarget"
         //Notification  
        headmsg "Creature Tamed"
        //playsound "ding.wav"
        setskill 'Animal Taming' 'locked'
        stop
      endif
    endfor
  else
    replay
  endif
endif

 

[Wooty]

Thank you for sharing